/* RxMUI by Alfonso Ranieri */
/* ghh RxMUI Register       */

signal on halt
signal on break_c

call Init         /* volá funkci Init */
call CreateApp    /* volá funkci CreateApp (hlavní program) */
call HandleApp    /* volá funkci HandleApp (hlavní event) */

/**************************************** přítomnost knihoven Alfie ****/
Init: procedure expose global.
    l="rmh.library";if ~show("L",l) then;if ~AddLib(l,0,-30) then exit
    if RMH_AddLibrary("rexxsupport.library","rxmui.library")~=0 then exit
    call Pragma("W","N")
    call RxMUIOpt("DebugMode ShowErr")
    return

/******************************************************** start gui ****/
CreateApp: procedure expose global.                          /* hlavní program */

    app.Title="RxMUI Register"                               /* název programu (v Exchange) */
    app.Version="$VER: RxMUI template 0.1 (02.11.2016)"      /* verze programu */
    app.Copyright="Donotpanicware ghh 2016"
    app.Author="ghh"
    app.Description="RxMUI Register"                         /* popis programu (v Exchange) */
    app.Base="RXMUIAPP"                                      /* název Arexx portu */
    app.SubWindow="win"                                      /* název hlavního okna "win" */
     win.ID="MWIN"                                           /* id hlavního okna */
     win.ScreenTitle="RxMUI Register"                        /* titulek na liště Workbenche */
     win.Title="Register"                                    /* titulek na okně */
     win.Contents="mgroup"                                   /* okno obsahuje hlavní skupinu s názvem "mgroup" */
      mgroup.0="regi"                                        /* skupina s registrem */
       regi.Class="Register"
       regi.Titles="One|Two|Three"                           /* tři záložky */
        regi.0=Button("thisbutton","This")                   /* obsah první - tlačítko */
        regi.1=Button("isbutton","is")                       /* druhé */
        regi.2=Button("coolbutton","cool!")                  /* třetí */
      mgroup.1="bgr"
       bgr.Class="Group"                                     /* třída Group */
       bgr.Horiz=1                                           /* horizontální */
        bgr.0=Button("okbutton","Ok")                        /* tlačítko Ok -  tlačítka jsou mimo skupinu s registrem */
        bgr.1=Button("quitbutton","Quit")                    /* tlačítko Quit */ /* konec popisu gui */

/*********************************************************** notify ****/
    if NewObj("Application","App")>0 then exit                            /* nový objekt - aplikace "App" */

    call Notify("win","CloseRequest",1,"App","ReturnID","QUIT")           /* opuštění programu zavřením okna */

    call Notify("thisbutton","Pressed",0,"App","Return","Say 'This'")     /* tlačítka v registrech */
    call Notify("isbutton","Pressed",0,"App","Return","Say 'is'")
    call Notify("coolbutton","Pressed",0,"App","Return","Say 'cool!'")
    call Notify("okbutton","Pressed",0,"App","Return","Say 'Ok'")         /* tlačítka v okně */
    call Notify("quitbutton","Pressed",0,"App","ReturnID","QUIT")

    call Set("win","Open",1)

    return

/*********************************************** hlavní event Alfie ****/
HandleApp: procedure expose global.

    ctrl_c=2**12
    do forever
        call NewHandle("App","h",ctrl_c)
        if and(h.signals,ctrl_c)>0 then exit
        select
            when h.event="QUIT" then exit
            otherwise interpret h.event
        end
    end

/****************************************************** exit signal ****/
halt:
break_c:
    exit